help needed getting pans back on top in walterized v3 theme - code included

[rhythmtech]

guys, im using apollo v3 theme with some mods. problem is i cant figure out how to get my pans back on top and labels at the bottom. any help appreciated.

heres my walter code:


use_pngs 1
use_lvgs 1
tcp_showborders 0
mcp_showborders 0
tcp_vupeakwidth 2
mcp_vupeakheight 4
mcp_mastervupeakheight 4
mcp_altmeterpos 0
use_overlays 0
transport_showborders 1
tcp_vol_zeroline 85000000
tcp_pan_zeroline 67000000
mcp_vol_zeroline 85000000
mcp_pan_zeroline 67000000
trans_speed_zeroline 99999999

; ----------WALTER------------


Layout "Divider"

clear tcp.*
set tcp.size [320 20]
set tcp.label w>22 [60 3 66 18 0 0 0 0]
set tcp.label.margin [2 0 0 0]
set tcp.label.color [0 99 0]
EndLayout ;

Layout "vertical label"

clear mcp.*
set mcp.size [16 245]
set mcp.label [0 0 16 500 0 0 0 1]
set mcp.label.color [177 177 177]
EndLayout




Layout "Red Faders" "fader_red"
set mcp.volume ?recarm [9 148 20 164 0 0 0 1]
EndLayout

Layout "Extended"
clear trans.*
set trans.size [520 60] [520 60]
set trans.size.minmax [520 60 520 95]
set trans.size.dockedheight [30]

set trans.sel !trans_docked [14 32 200 20 1 0 1 0] [14 32 200 20 1 0 1 0]
; set trans.bpm.tap w<490 [0] [330 3 38 20 1 0 1 0] [330 3 38 20 1 0 1 0]
set trans.bpm.edit !trans_docked w<420 [0] [418 30 46 20 1 0 1 0] [179 5 46 20 1 0 1 0]
set trans.bpm.edit.color [119 235 5]
set trans.curtimesig !trans_docked [418 8 46 20 1 0 1 0] [120 5 46 20 1 0 1 0]

set trans.status !trans_docked [230 16 170 26 0 0 bxfac 0] [360 3 230 23 0 0 bxfac 0]
set trans.rate !trans_docked [14 60 200 20 bxfac 0 bxfac 0] [14 60 200 20 bxfac 0 bxfac 0]
set trans.rate.fader !trans_docked [218 59 195 20 0 0 bxfac 0] [218 59 195 20 0 0 bxfac 0]
set trans.rate.color [119 235 5]

set trans.play !trans_docked [139 3 24 24 bxfac 0 bxfac 0] [277 2 24 24 bxfac 0 bxfac 0]
set trans.stop !trans_docked [114 3 24 24 bxfac 0 bxfac 0] [253 2 24 24 bxfac 0 bxfac 0]
; set trans.pause [251 2 24 24 bxfac 0 bxfac 0]
set trans.rec !trans_docked [164 3 24 24 bxfac 0 bxfac 0] [301 2 24 24 bxfac 0 bxfac 0]
set trans.repeat !trans_docked [39 3 24 24 bxfac 0 bxfac 0] [181 2 24 24 bxfac 0 bxfac 0]
set trans.rew !trans_docked [64 3 24 24 bxfac 0 bxfac 0] [205 2 24 24 bxfac 0 bxfac 0]
set trans.fwd !trans_docked [89 3 24 24 bxfac 0 bxfac 0] [229 2 24 24 bxfac 0 bxfac 0]
set trans.automode !trans_docked [476 15 30 30 bxfac 0 bxfac 0] [740 1 30 30 bxfac 0 bxfac 0]

EndLayout

clear trans.*
set trans.size [1041 85]
set trans.size.minmax [500 40 2048 200]
set trans.size.dockedheight w<300 [84] [43]
set trans.margin [0 0 0 0]
set trans_center_offset h<85 ?trans_flags&1 w<1030 [301] [365] [0] [0]
set trans_center_negoffset h<111 ?trans_flags&1 [0] [232] [232]
set trans_slot [32]
set trans_grid [2 2 33 35]
set trans.rew + trans_center_offset + trans_grid * [0] trans_slot
set trans.play + trans_center_offset + trans_grid * [2] trans_slot
set trans.pause + trans_center_offset + trans_grid * [3] trans_slot
set trans.stop + trans_center_offset + trans_grid * [1] trans_slot
set trans.fwd + trans_center_offset + trans_grid * [5] trans_slot
set trans.rec + trans_center_offset + trans_grid * [4] trans_slot
set trans.repeat + trans_center_offset + trans_grid * [6] trans_slot
set trans.automode + [2 2 59 33] trans_center_negoffset
set trans.status h<85 + w<1030 [69 2 220 17] [69 2 292 33] trans_center_negoffset [2 66 1037 17 0 0 1 1]
set trans.status.margin w<1030 [5 0 5 0] [7 3 7 3]
set trans.bpm.tap h<85 w<1030 [532 2 33 17] [600 2 33 17] [301 2 33 17]
set trans.bpm.tap.color [58 64 63]
set trans.bpm.edit h<85 w<1030 [532 19 33 16] [600 19 33 16] [301 19 33 16]
set trans.bpm.edit.color [127 148 148]
set trans.bpm.edit.margin [0 0 0 0 0.5]
set trans.curtimesig h<85 ?trans_flags&4 w<1030 [572 2 33 33] [640 2 33 33] [0] [341 2 33 33]
set trans.rate h<85 ?trans_flags&2 ?trans_flags&4 w<1030 [612 2 120 17 0 0 0.1 0] [680 2 120 17 0 0 0.25 0] w<1030 [572 2 120 17 0 0 0.1 0] [640 2 120 17 0 0 0.25 0] [0] [229 42 70 17 0 0 0 0]
set trans.rate.fader h<85 ?trans_flags&2 ?trans_flags&4 w<1030 [612 18 120 17 0 0 0.1 0] [680 18 120 17 0 0 0.25 0] w<1030 [572 18 120 17 0 0 0.1 0] [640 18 120 17 0 0 0.25 0] [0] [299 42 252 17 0 0 0.1 0]
set trans.sel h<85 w<1030 + [69 18 220 17 0 0 0 0] trans_center_negoffset [814 2 220 17 1 0 1 0] [2 42 220 17 0 0 0 0]

;GlobalLayout "name"

[rhythmtech]

anyone?

[Aeolian]

It looks like your Walter doesnt have a default layout for mcp, so its using the "default_layouts" in Reaper>Plugins for the mcp (which i bet has panners at bottom for backwards compatibilty).

your DEFAULT layout needs everything defined, i cant see any "set mcp.pan" in your code.

Check out the default v4 mcp below



clear mcp.*

set mcp.size [73 392]
set mcp.trackidx [0 0 35 18 0 0 0 0]
set mcp.trackidx.margin [7 4 3 4 0]
set mcp.trackidx.color ?recarm [153 52 54] [35 38 38]
set mcp.label [1 18 71 18 0 0 0 0]
set mcp.label.margin [2 0 2 0 0.5]
set mcp.label.color ?recarm [180 106 106] [194 204 204]
set mcp.mute [8 43 29 20 0 0 0 0]
set mcp.solo [37 43 28 20 0 0 0 0]
set mcp.meter h<380 h<320 [33 93 32 207 0 0 0 1] [33 107 32 178 0 0 0 1] [33 107 32 163 0 0 0 1]
set mcp.volume h<380 h<320 [8 93 18 215 0 0 0 1] [8 107 18 185 0 0 0 1] [8 107 18 170 0 0 0 1]
set mcp.pan [8 68 57 18 0 0 0 0]
set mcp.volume.label h<320 [0] [8 93 29 7 0 0 0 0]
set mcp.volume.label.color [71 80 84]
set mcp.pan.label h<320 [0] [40 93 28 7 0 0 0 0]
set mcp.pan.label.color [71 80 84]
set mcp.folder [48 4 20 11 0 0 0 0]
set mcp.phase h<380 h<320 [8 308 18 20 0 1 0 1] [8 292 18 20 0 1 0 1] [8 277 18 20 0 1 0 1]
set mcp.io ?recarm h<380 [8 369 21 16 0 1 0 1] [8 367 21 18 0 1 0 1] h<380 [8 369 57 16 0 1 0 1] [8 367 57 18 0 1 0 1]
set mcp.env h<380 h<320 ?recarm [0] [8 353 57 16 0 1 0 1] [8 353 57 16 0 1 0 1] [8 346 57 18 0 1 0 1]
set mcp.fx h<380 h<320 ?recarm [27 335 38 18 0 1 0 1] [46 335 19 18 0 1 0 1] [27 319 38 18 0 1 0 1] [27 304 38 18 0 1 0 1]
set mcp.fxbyp h<380 h<320 ?recarm [8 335 19 18 0 1 0 1] [27 335 19 18 0 1 0 1] [8 319 19 18 0 1 0 1] [8 304 19 18 0 1 0 1]
set mcp.fxin ?recarm h<380 [29 369 36 16 0 1 0 1] [29 367 36 18 0 1 0 1] [0]
set mcp.recarm h<380 h<320 [33 300 32 28 0 1 0 1] [33 284 32 28 0 1 0 1] [33 269 32 28 0 1 0 1]
set mcp.recmon h<380 h<320 ?recarm [8 353 19 16 0 1 0 1] [8 335 19 18 0 1 0 1] [8 337 19 16 0 1 0 1] [8 325 19 18 0 1 0 1]
set mcp.recmode h<380 h<320 ?recarm [27 353 38 16 0 1 0 1] [0] [27 337 38 16 0 1 0 1] [27 325 38 18 0 1 0 1]
set mcp.extmixer.mode [0]

[rhythmtech]

see that means nothing at all to me :-D

all i know is that the small code on top was the original code and i just added little bits of walter to it from other themes and asking questions.

would i be right in thinking that i could replace the v4 defaults_layout with a v3 and i'd have them on top again?

if not then im stumped.

[rhythmtech]

any more help? i've really no idea whats going on with walter :-/

is there a bit of code i could drop in?

plain english please, im an audio engineer with no clue of graphics.. i just want my pans back on top :-D

[Aeolian]

upload your theme to the stash and ill put the panners on top for you.

-OR-

paste this code below into your rtconfig "vertical label" layout, just underneath the "set mcp.size [16 245]" line

set mcp.pan [3 176 65 20 0 1 0 1]


now your "vertical label" layout will look like this

Layout "vertical label"

clear mcp.*
set mcp.size [16 245]
set mcp.pan [3 176 65 20 0 1 0 1]
set mcp.label [0 0 16 500 0 0 0 1]
set mcp.label.color [177 177 177]
EndLayout



Now, the 176 number (bolded) is what will set your panner position height.
The lower this number (20, 40, 42 etc) the higher up your panner will go.
The higher it is, it will appear lower down on the mixer.

At 176, its gonna appear at the bottom somewhere.
If you lower this 176 number (to, say, 40 or 30) its gonna automagically appear higher up the mixer.
After you have changed it, it should eg look like this

set mcp.pan [3 40 65 20 0 1 0 1]


You need to find the perfect spot for it, via trial and error (ie adjusting the number repeatedly till it is EXACTLY were you want it)

I dont know what that exact number is because i dont have Apollo in front of me

Let me know how you go. Dont forget to refresh your theme after each saved change to the rtconfig, to show your changes

[rhythmtech]

Originally Posted by Aeolian

upload your theme to the stash and ill put the panners on top for you.

-OR-

paste this code below into your rtconfig "vertical label" layout, just underneath the "set mcp.size [16 245]" line

set mcp.pan [3 176 65 20 0 1 0 1]


now your "vertical label" layout will look like this

Layout "vertical label"

clear mcp.*
set mcp.size [16 245]
set mcp.pan [3 176 65 20 0 1 0 1]
set mcp.label [0 0 16 500 0 0 0 1]
set mcp.label.color [177 177 177]
EndLayout



Now, the 176 number (bolded) is what will set your panner position height.
The lower this number (20, 40, 42 etc) the higher up your panner will go.
The higher it is, it will appear lower down on the mixer.

At 176, its gonna appear at the bottom somewhere.
If you lower this 176 number (to, say, 40 or 30) its gonna automagically appear higher up the mixer.
After you have changed it, it should eg look like this

set mcp.pan [3 40 65 20 0 1 0 1]


You need to find the perfect spot for it, via trial and error (ie adjusting the number repeatedly till it is EXACTLY were you want it)

I dont know what that exact number is because i dont have Apollo in front of me

Let me know how you go. Dont forget to refresh your theme after each saved change to the rtconfig, to show your changes

thank you!

and thank you for putting it in simple terms for me. it makes a lot more sense when there's reason applied.

ill do it tomorrow and let you know how it went.

[Aeolian]

The 1st thing you should notice is that the pan label (30%R, center) now needs to move as well

here is the code for pan labels (from default_layouts)


set mcp.pan.label [39 197 29 13 0 1 0 1]


Paste that line above directly underneath "set mcp.pan" and then fiddle with the second number (197), making it smaller, until it lines up to where you want it.

your "vertical labels" should now look like this

Layout "vertical label"

clear mcp.*
set mcp.size [16 245]
set mcp.pan [3 176 65 20 0 1 0 1]
set mcp.pan.label [39 197 29 13 0 1 0 1]
set mcp.label [0 0 16 500 0 0 0 1]
set mcp.label.color [177 177 177]
EndLayout

[rhythmtech]

vertical labels was just a bit of code to use as a divider so there's no pans on it.

but i assume i apply everything you said to the MCP layouts?

[Aeolian]

Right .... i thought that layout was a tad bare

Yep ..... it only applies to your mcp layouts.


Just try it on one layout 1st, see your results, and if you like what you see, copy/paste that part over to other mcp layouts

[rhythmtech]

thanks for all your help.