Old 01-23-2013, 06:14 PM   #1
Xane002
Human being with feelings
 
Join Date: Aug 2009
Posts: 91
Default Themers...Can Walter Do This?

I under estimated the usefulness of themes in use with a DAW. It does make a difference!

Apollo and now Janne are my favorites.

So far, Reaper has been able to do everything I've wanted to do but it has taken a considerable amount of time - not time used in recording or creating...but simply setting things up! That's the upside, and downside of Reaper.

So, before I venture into a new area called Walter and invest even more time, please tell me if this should be possible...

Can you make a mixer panel that's nothing but Send controls?

It seems that naturally, the fader will be the most common element. The themes I've seen make variations on the fader size, the VU, etc. But, I haven't seen a mixer panel with Sends only, or Inserts only. So, I wonder if it's possible.

Why this is desired is that for my live show, I use a lot of sends and the fader of the track is pretty much irrelevant or useless since the signal is piped out pre-fader.

I don't mind learning how to do this, but if someone familiar with themes can tell me if a "sends only" panel is possible, I'll jump right in.

Thanks!
Xane002 is offline   Reply With Quote
Old 01-23-2013, 06:52 PM   #2
Janne83
Human being with feelings
 
Join Date: May 2010
Location: Earth
Posts: 1,883
Default

Its possible to have just sends and inserts area as a layout.

Youll need to look into the extmixer element of the walter code. It controls the position of the insert/send area.


set mcp.extmixer.mode [1]
set mcp.extmixer.position [here you set the desired numbers for positioning]

Look into the guides for WALTER at the top of color themes forum area.


REgards J
__________________
Win11, R 64bit

Last edited by Janne83; 01-23-2013 at 06:59 PM.
Janne83 is offline   Reply With Quote
Old 01-23-2013, 07:29 PM   #3
Xane002
Human being with feelings
 
Join Date: Aug 2009
Posts: 91
Default

Quote:
Originally Posted by Janne83 View Post
Its possible to have just sends and inserts area as a layout.

Youll need to look into the extmixer element of the walter code. It controls the position of the insert/send area.


set mcp.extmixer.mode [1]
set mcp.extmixer.position [here you set the desired numbers for positioning]

Look into the guides for WALTER at the top of color themes forum area.


REgards J
Thank you!!
Xane002 is offline   Reply With Quote
Old 01-23-2013, 07:32 PM   #4
witti
Human being with feelings
 
witti's Avatar
 
Join Date: May 2012
Posts: 1,216
Default

This layout is for the Apollo_A theme. Put the text at the end of the mcp section in the rtconfig file.

If only sends are active (mixer menu) this layout will show just the sends. Otherwise it will look like the default layout.


Layout "25. Sends"
clear mcp.*
set mcp.size [81 400]
front mcp.width.label mcp.recinput mcp.trackidx mcp.fxin
; MARGIN
set mcp.label.margin [3 0 3 0 0.5]
set mcp.trackidx.margin [6 -1 0 0 0]
set mcp.fxlist.margin [5 0 4 0 0]
set mcp.fxparm.margin [4 0 2 0 0]
set mcp.sendlist.margin [5 0 3 0 0]
set mcp.volume.label.margin [-33 1 0 0 0.5]
set mcp.pan.label.margin trackpanmode<4 [3 0 0 0 0.5] [-32 0 0 0 0.5]
set mcp.width.label.margin [1 0 0 0 0.5]
set mcp.recinput.margin [5 0 4 0 0.5]
set mcp.meter.vu.div [1]
; Mode
set mcp.extmixer.mode [1]
set mcp.extmixer.position ?mcp_wantextmix&1 [2 5 77 89 0 0 0 1] ?mcp_wantextmix&2 [2 5 77 366 0 0 0 1] ?mcp_wantextmix&4 [2 5 77 89 0 0 0 1] [2 5 77 89 0 0 0 1]
set mcp.pan.fadermode [1]
set mcp.width.fadermode [1]
; FOLDER/NAME
set mcp.folder folderstate<0 [68 387 12 12 0 1 0 1] [0 387 12 12 0 1 0 1]
set mcp.label [3 380 74 15 0 1 0 1]
; IO/ID
set mcp.io ?mcp_wantextmix&1 [3 96 74 22 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [3 96 74 22 0 1 0 1] [3 4 74 22 0 0 0 0]
set mcp.trackidx ?mcp_wantextmix&1 [3 96 36 22 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [3 96 36 22 0 1 0 1] [3 4 36 22 0 0 0 0]
; BUTTONS
set mcp.solo ?mcp_wantextmix&1 [58 159 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 159 20 20 0 1 0 1] [58 67 20 20 0 0 0 0]
set mcp.mute ?mcp_wantextmix&1 [58 179 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 179 20 20 0 1 0 1] [58 87 20 20 0 0 0 0]
set mcp.phase ?mcp_wantextmix&1 [58 200 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 200 20 20 0 1 0 1] [58 108 20 20 0 0 0 0]
set mcp.env ?mcp_wantextmix&1 [58 226 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 226 20 20 0 1 0 1] [58 134 20 20 0 0 0 0]
set mcp.fx ?mcp_wantextmix&1 [58 248 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 248 20 20 0 1 0 1] [58 156 20 20 0 0 0 0]
set mcp.fxbyp ?mcp_wantextmix&1 [58 270 20 13 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 270 20 13 0 1 0 1] [58 178 20 13 0 0 0 0]
set mcp.fxin ?mcp_wantextmix&1 [44 357 30 12 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [44 357 30 12 0 1 0 1] [44 357 30 12 0 1 0 1]
set mcp.recarm ?mcp_wantextmix&1 [58 334 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 334 20 20 0 1 0 1] [58 334 20 20 0 1 0 1]
set mcp.recmon ?mcp_wantextmix&1 [58 312 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 312 20 20 0 1 0 1] [58 312 20 20 0 1 0 1]
set mcp.recmode ?mcp_wantextmix&1 [58 290 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [58 290 20 20 0 1 0 1] [58 290 20 20 0 1 0 1]
; FADER/KNOBS
set mcp.volume ?mcp_wantextmix&1 [3 159 20 194 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [3 159 20 194 0 1 0 1] [3 67 20 286 0 0 0 1]
set mcp.pan ?mcp_wantextmix&1 trackpanmode<4 [30 119 20 20 0 1 0 1] [13 119 20 20 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 trackpanmode<4 [30 119 20 20 0 1 0 1] [13 119 20 20 0 1 0 1] trackpanmode<4 [30 27 20 20 0 0 0 0] [13 27 20 20 0 0 0 0]
set mcp.width ?mcp_wantextmix&1 trackpanmode>=4 [47 119 20 20 0 1 0 1] [0] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 trackpanmode>=4 [47 119 20 20 0 1 0 1] [0] trackpanmode>=4 [47 27 20 20 0 0 0 0] [0]
; LABEL
set mcp.volume.label ?mcp_wantextmix&1 [4 356 72 14 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [4 356 72 14 0 1 0 1] [4 356 72 14 0 1 0 1]
set mcp.pan.label ?mcp_wantextmix&1 [4 142 72 14 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [4 142 72 14 0 1 0 1] [4 50 72 14 0 0 0 0]
set mcp.width.label ?mcp_wantextmix&1 trackpanmode>=4 [40 142 36 14 0 1 0 1] [0] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 trackpanmode>=4 [40 142 36 14 0 1 0 1] [0] trackpanmode>=4 [40 50 36 14 0 0 0 0] [0]
set mcp.recinput ?mcp_wantextmix&1 ?recarm [4 142 72 14 0 1 0 1] [0] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 ?recarm [4 142 72 14 0 1 0 1] [0] ?recarm [4 50 72 14 0 0 0 0] [0]
; METER
set mcp.meter ?mcp_wantextmix&1 [28 161 25 190 0 1 0 1] ?mcp_wantextmix&2 [0] ?mcp_wantextmix&4 [28 161 25 190 0 1 0 1] [28 69 25 282 0 0 0 1]
; COLOR
set mcp.label.color [25 25 25]
set mcp.trackidx.color ?recarm [232 58 13] [192 204 204]
set mcp.volume.label.color [204 199 172]
set mcp.pan.label.color [187 187 187]
set mcp.width.label.color [187 187 187]
set mcp.recinput.color ?recarm [232 58 13] [160 160 160]
set mcp.volume.color [255 255 255 225 0 0 0 0]
set mcp.pan.color [9 234 253 225 0 0 0 0]
set mcp.width.color trackpanmode=6 [9 234 253 225 0 0 0 0] [253 209 9 225 0 0 0 0]
set mcp.meter.readout.color [220 220 220 220 220 220 220 220]
set mcp.meter.scale.color.unlit.top [0 0 0 0]
set mcp.meter.scale.color.unlit.bottom [0 0 0 0]
EndLayout ; end of "25. Sends"

Edit: Ok. I found out that you can leave "Show Parameter" ticked. Anyway, this layout gives you the possibility to show a long row of sends if you want or to switch back to the default layout if you don't need them anymore.

Last edited by witti; 01-23-2013 at 07:56 PM.
witti is offline   Reply With Quote
Old 01-23-2013, 11:05 PM   #5
Xane002
Human being with feelings
 
Join Date: Aug 2009
Posts: 91
Default

Witti,

Thanks for the quick mod to Apollo_A!

After figuring out how to apply the mod (total newb on themes)...what you've done it exactly what I was looking for!

Thank you!

And then...playing with some of the other layout options, I found Sidebar to be almost as good but in fact, more useful in other track cases.

Here's a screen print of what I have set up.

Thanks again for the help, and theme!
Attached Images
File Type: jpg reaper_apollo_sends.jpg (65.6 KB, 325 views)
Xane002 is offline   Reply With Quote
Reply

Thread Tools
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump


All times are GMT -7. The time now is 06:15 AM.


Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2024, vBulletin Solutions Inc.